***********************************************************************
***********           PANJIT International Co Ltd           ***********
***********************************************************************
*June 19, 2025                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt DI1510S   DC+ AC1 AC2 DC-
.param
+vc0 = 1.052e-9		vc1 = 6.783e-10		vc2 = 5.017e-1		vc3 = 4.035e-9		vc4 = 1.837e-3
+tc1 = 8.052e-2		tc2 = 4.272e-2		tc3 = 3.542e-2		tc4 = 1.312e-2	   
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d12 AC1 DC+ diode
g12 DC+ AC1 value = {irexp(v(DC+,AC1))}
d13 AC2 DC+ diode
g13 DC+ AC2 value = {irexp(v(DC+,AC2))}
d24 DC- AC1 diode
g24 AC1 DC- value = {irexp(v(AC1,DC-))}
d34 DC- AC2 diode
g34 AC2 DC- value = {irexp(v(AC2,DC-))}
.model diode d
***** flag parameter *****
+level = 1        
***** dc model parameter *****
+ is = 3.279e-9	   	  n = 1.745		  rs = 2.019e-2		ikf = 6.095
+ibv = 1e-3		nbv = 1.000		  bv = 1100
***** capacitance parameter *****
+cjo = 3.567e-11	  m = 2.485e-1		  vj = 3.909e-1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		 eg = 1.100		 xti = 3
+trs1 = -1.674e-4      trs2 = 8.817e-6
.ends DI1510S
*$
